JSI Tip 5843. How can I increase the number of folders that Windows XP remembers settings for?

By default, Windows XP remembers your settings for 400 folders.

I have scripted NumFolders.bat to change that limit.

The syntax for using NumFolders.bat is:

NumFolders Number

where Number is the number of folders to remember settings for, in the range of 0 - 99999.

NOTE: NumFolders.bat calls Dec2Hex.bat.

NumFolders.bat contains:

@echo off
setlocal
if \{%1\}==\{\} goto syntax
set /a num=%1
if %num% LSS 0 goto syntax
if %num% GTR 99999 goto syntax
call Dec2Hex %num% hex chars
if not defined chars goto syntax
if %chars% EQU 0 goto syntax
set hexzero=00000000
set /a numzero=8 - %chars%
call set dwhex=%%hexzero:~0,%numzero%%%
set dwhex=%dwhex%%hex%
@echo REGEDIT4>"%temp%\NumFolders.reg"
@echo.>>"%temp%\NumFolders.reg"
@echo \[HKEY_CURRENT_USER\Software\Microsoft\Windows\Shell\]>>"%temp%\NumFolders.reg"
@echo "BagMRU Size"=dword:%dwhex%>>"%temp%\NumFolders.reg"
@echo.>>"%temp%\NumFolders.reg"
@echo \[HKEY_CURRENT_USER\Software\Microsoft\Windows\ShellNoRoam\]>>"%temp%\NumFolders.reg"
@echo "BagMRU Size"=dword:%dwhex%>>"%temp%\NumFolders.reg"
@echo.>>"%temp%\NumFolders.reg"
regedit /s "%temp%\NumFolders.reg"
del /q "%temp%\NumFolders.reg"
endlocal
goto :EOF
:syntax
@echo Syntax: NumFolders Number
endlocal
goto :EOF