JSI Tip 8814. How can I remove the Show updates feature in Windows XP SP2?

I explained the Show updates feature in How does the 'Show updates' check box in the 'Add or Remove Programs' applet of the Windows XP SP2 Control Panel work?

The Show updates feature is enabled by default in Windows XP SP2, but the Show updates check box is un-checked by default.

I have scripted DontGroupPatches.bat to disable (or enable) the Show updates feature on all Windows XP workstations in your domain, including those that are NOT yet running SP2, so your setting will be available when the computer is updated.

NOTE: The DontGroupPatches.bat script uses NetViewC.bat, which must be located in a folder that is in your PATH.

The syntax for using DontGroupPatches.bat is:

DontGroupPatches ON|OFF \[NetBIOS_Domain_Name\]

Where the first parameter is ON to enable the feature, or OFF to disable it, and NetBIOS_Domain_Name is an optional parameter to specify a different domain that the one you are logged onto when running the script.

DontGroupPatches.bat contains:

@echo off
setlocal
if \{%1\}==\{\} goto err
set onoff=%1
if /i "%onoff%" EQU "ON" goto OK
if /i "%onoff%" EQU "OFF" goto OK
goto err 
:ok
set qry=REG QUERY
set add=REG ADD
set data=0
if /i "%onoff%" EQU "ON" set data=1
set dom=%2
if defined USERDNSDOMAIN if not defined dom set dom=%USERDOMAIN%
if not defined dom goto err
for /f %%a in ('netviewc %dom%') do (
 for /f "Tokens=2*" %%r in ('%qry% "%%a\HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentVersion^|find "REG_SZ"') do (
  if "%%s" EQU "5.1" @echo %%a&%add% "%%a\HKLM\Software\Microsoft\Windows\CurrentVersion\Policies\Uninstall" /v DontGroupPatches /T REG_DWORD /D %data% /F
 )
)
endlocal
goto :EOF
:err
@echo Syntax: DontGroupPatches ON^|OFF \[NetBIOS_Domain_Name\]
endlocal