JSI Tip 7952. You cannot install the February 13, 2002 Security Update from the Windows Update site?


The subject behavior will occur if you are using a MDAC (Microsoft Data Access Components) version that is later than 2.6.

I have scripted MDAC20020213.bat to fake out the Security Update.

To use MDAC20020213.bat, follow these steps:

1. Open a CMD.EXE window.

2. Type MDAC20020213 /F and press Enter.

3. When you receive the following message, visit the Windows Update site and install the February 13, 2002 Security Update:

You may now install the Security Update, February 13, 2002 from the Windows Update Web site.

4. After the Security Update has been applied, type MDAC20020213 /R and press Enter.

5. When you receive the DataAccess restoration was successful message, close the CMD.EXE window.

MDAC20020213.bat contains:


@echo off
if \{%1\}==\{\} @echo Syntax: MDAC20020213 /\[F^|R\]&goto :EOF
if /i "%1" EQU "/F" goto fix
if /i "%1" EQU "/R" goto restore
@echo Syntax: MDAC20020213 /\[F^|R\]
goto :EOF
:fix
regedit /a "%UserProfile%\My Documents\MDAC_Old.reg" "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DataAccess"
@echo REGEDIT4>"%TEMP%\MDAC_Fix.reg"
@echo.>>"%TEMP%\MDAC_Fix.reg"
@echo \[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DataAccess\]>>"%TEMP%\MDAC_Fix.reg"
@echo "FullInstallVer"="2.60.6526.3">>"%TEMP%\MDAC_Fix.reg"
@echo "Version"="2.60.6526.3">>"%TEMP%\MDAC_Fix.reg"
@echo.>>"%TEMP%\MDAC_Fix.reg"
@echo.>>"%TEMP%\MDAC_Fix.reg"
if not exist "%TEMP%\MDAC_Fix.reg" @echo Error - MDAC20020213 could not write "%TEMP%\MDAC_Fix.reg"&goto :EOF
regedit /s "%TEMP%\MDAC_Fix.reg"
del /q "%TEMP%\MDAC_Fix.reg"
@echo You may now install the Security Update, February 13, 2002 from the Windows Update Web site.
goto :EOF
:restore
if exist "%UserProfile%\My Documents\MDAC_Old.reg" goto restore1
@echo Error - MDAC20020213 could not locate the registry backup, "%UserProfile%\My Documents\MDAC_Old.reg", to restore.
goto :EOF
:restore1
regedit /s "%UserProfile%\My Documents\MDAC_Old.reg"
del /q "%UserProfile%\My Documents\MDAC_Old.reg"
@echo DataAccess restoration was successful.



Hide comments

Comments

  • Allowed HTML tags: <em> <strong> <blockquote> <br> <p>

Plain text

  • No HTML tags allowed.
  • Web page addresses and e-mail addresses turn into links automatically.
  • Lines and paragraphs break automatically.
Publish